BRegexp for Squeak

Perl5互換の正規表現をSqueak上から利用するためのライブラリです
日本語文字列の取り扱いが可能です
現状では、Windows環境からの利用に限定されています
正規表現エンジンの BREGEXP.DLL （Tatsuo Baba氏, http://www.hi-ho.ne.jp/babaq/）を、秀丸マクロ向けに開発された BREGEXP.DLL のラッパー BRE_Wrap.dll （杉浦まさき氏, http://www.ceres.dti.ne.jp/~sugiura/）を介して利用しています

動作確認

Squeak3.6
SqueakNihongo6.1

ダウンロード

BRegexp.sar Ver.002 (2004/05/09)

BRegexpTest.st　テストケース
BRegexpMultiStringTest.st　テストケース（Nihongo6.1）

ライセンス

本ライブラリのSqueakコード部分は、SqueakLicense （本文、日本語訳）とします。ご自由にお使いください。
同梱の BREGEXP.DLL、BRE_Wrap.dll は開発者各氏の著作物で、SqueakLicenseの適用外です。利用や配布の際はそれぞれのライセンスをご確認ください。
参考：各DLLのライセンス記載場所(2004年5月15日時点、共に制限はかなり緩いものです)

BREGEXP.DLL ： http://www.hi-ho.ne.jp/babaq/bregexp.html
BRE_Wrap.dll ： http://www.ceres.dti.ne.jp/~sugiura/hidemaru/macros/dgserver/bre_wrap.txt

使用方法

使用可能な正規表現パターンは、BREGEXP.DLL に準じます。詳しくはそちらのサイト、またはその他Perl互換の正規表現を解説したサイトをご参照ください。

■Match

正規表現パターンに最初に一致した部分文字列の範囲をラップしたオブジェクト（BMatchResultオブジェクト）を返します。
また、パターン中の丸括弧に一致した部分文字列を、BRegexp >> hasNext で有無のチェック、 BRegexp >> nextResult で取得することができます。
返り値の BMatchResult オブジェクトに isMatched メッセージを送ると、一致した部分があったか否かを判別することができます。
また、BMatchResult オブジェクトに asString 、もしくは extractSubstringFrom: メッセージを送ると一致した文字列を取得することができます。ただし、asString では BRegexp オブジェクトのリリース後では正しい文字列を取得することができません。

メソッド： BRegexp >> match:from:
第１引数： String ：正規表現パターンの文字列
第２引数： String ：対象文字列
返り値： BMatchResult ：正規表現パターンに一致した部分文字列の範囲をラップしたオブジェクト


| pattern target reg result |
reg := BRegexp default.
pattern := 'm/(\d{2})/'.
target := 'Smalltalk-80'.

^ [result := reg match: pattern from: target.
   result asString]
      ensure: [reg release]
	

===> '80'


| pattern target reg result |
reg := BRegexp default.
pattern := '/(\d{1,4})-(\d{1,4})-(\d{4})/'.
target := '03-765-5678'.

result := reg match: pattern from: target.
result isMatched 
    ifTrue: [Transcript cr; show: result asString]
    ifFalse: [Transcript cr; show: 'not matched'].

[[reg hasNext] whileTrue: [
    result := reg nextResult.
    Transcript cr; show: result asString.
]] ensure: [reg release].


Transcript ===> 03-765-5678
Transcript ===> 03
Transcript ===> 765
Transcript ===> 5678

■Substitute

正規表現パターンに一致した部分を、パターン内に指定した文字列で置換します。

メソッド： BRegexp >> substitute:from:
第１引数： String ：正規表現パターンの文字列
第２引数： String ：対象文字列
返り値： String ：置換後の文字列


| pattern target reg |
reg := BRegexp default.
pattern := 's/(\d\d)-\d{4}-\d{4}/$1-xxxx-xxxx/'.
target := 'Yokohama 045-222-1111  Osaka 06-5555-6666'.

^ [reg substitute: pattern from: target]
      ensure: [reg release].


===> 'Yokohama 045-222-1111  Osaka 06-xxxx-xxxx'

■Translate

正規表現パターン通りに、パターン内に指定した文字列で置換します。

メソッド： BRegexp >> translate:from:
第１引数： String ：正規表現パターンの文字列
第２引数： String ：対象文字列
返り値： String ：置換後の文字列


| pattern target reg |
reg := BRegexp default.
pattern := 'tr/Ts/tS/'.
target := 'smallTalk'.

^ [reg translate: pattern from: target] 
      ensure: [reg release].


===> 'Smalltalk'

■Split

正規表現パターンを区切り文字列とし、対象文字列を分割します。
分割された文字列は、BRegexp >> hasNext で有無のチェック、 BRegexp >> nextResult で部分文字列の範囲をラップしたオブジェクト（BMatchResultオブジェクト）を取得することができます。返り値の BMatchResult オブジェクトに isMatched メッセージを送ると、一致した部分があったか否かを判別することができます。
また、BMatchResult オブジェクトに asString 、もしくは extractSubstringFrom: メッセージを送ると一致した文字列を取得することができます。
ただし、asString では BRegexp オブジェクトのリリース後では正しい文字列を取得することができません。

メソッド： BRegexp >> translate:from:limit:
第１引数： String ：正規表現パターンの文字列
第２引数： String ：対象文字列
第３引数： Integer ：最大分割数（０は制限なし）
返り値： Integer ：分割された数


| pattern target reg |
pattern := '/ *\d{2,3}-\d{3,4}-\d{4} */'.
target := 'Yokohama 045-222-1111  Osaka 06-5555-6666  Tokyo 03-1111-9999'.
reg := BRegexp default.

[
    reg split: pattern from: target limit: 0.
    [reg hasNext] whileTrue: [
        Transcript cr; show: reg nextResult asString.
    ].
] ensure: [reg release].


Transcript ===> Yokohama
Transcript ===> Osaka
Transcript ===> Tokyo